|
|
Post by Spirithawke on Dec 12, 2012 9:16:33 GMT
I have no idea where this should really be posted, and sadly I am not even sure if anyone still does anything with Morrowind here as the Morrowind section seems to have not been used in a long time and I recently started playing again. Anyways, I had my own wolf and other companions many years ago when I last played, sadly that computer is broken currently, so I went around looking for a mod I could just download and use which led me here to Emma & Grumpy's stuff (both names I remember vaguely from way back when) So I downloaded various companions to play around with. I noted the wolf never moves out of your way if he is say blocking a doorway. I went and looked at the script from him as I used to do my own scripting back then too and saw he did not have the bump code, so I added it. Back in game I ran across the same problem my old animal companions had, the fact that the default movement of them is flaky unless the ground is perfectly level (often still flaky even then). Being older and wiser now, I came up with a solution that so far seems to work. Have the script make him basically jump straight up for a distance of 150 so you can walk under him after it puts him into wander mode. As he wanders he goes back down to the ground and re-enters follow mode like he should. Here is a copy of how I changed his script: Begin 1A_Spotscript2
; the script is based on Grumpy's work and includes parts of the scripting from Wolf Companion ver 2.1, Constance and Beryl. CdCooley and Peter have helped me
; - Emma - to optimize it for creature companions.
; I have done some more optimizing of the script, also added in code for him to move out the way if the PC is too close and to levitate with the player. - Spirithawke
short p_speed
short p_health
short p_strength
short p_agility
short p_endurance
short stayoutside
short talkie
short warp
short doOnce1
short doOnce2
short fcounter
short p_level
short no_warp_check
short flycheck ;Spirithawke change
short movecheck ;Spirithawke change
short noGreet ;Sprithawke change
float timer
float movex ;Sprithawke change
float movey ;Sprithawke change
float movez ;Sprithawke change
float px
float py
float ax
float ay
float az
float bx
float by
float bz
float t1
float t2
float t3
float t4
float coDist1
float coDist2
if ( MenuMode == 1 )
if ( GetPCSleep == 0 )
return
endif
endif
;Begin Spirithawke change
if ( fcounter < 20 )
set fcounter to ( fcounter + 1 )
return
endif
set fcounter to 0
;End Spirithawke change
if ( talkie < 2 )
AddTopic "-Follow..."
AddTopic "-Health..."
AddTopic "-Tricks..."
AddTopic "-Stay outside..."
AddTopic "-my wolf companion"
AddTopic "-Combat..."
set p_level to ( Player->GetLevel )
set p_health to ( 10 * p_level + 50 )
set p_strength to ( 2 * p_level + 50 )
sethealth p_health
setstrength p_strength
set talkie to 2
return
endif
;Begin Spirithawke change
if ( movecheck == 1 )
if ( GetDistance Player > 160 )
set noGreet to 0
AIFollow Player 0 0 0 0
set movecheck to 0
return
endif
endif
;End Spirithawke change
if ( GetCurrentAIPackage == 3 )
;Begin Spirithawke change
if ( GetDistance Player < 132 ) ;had to be more than standard 80 to work correctly
set movex to ( 1A_comp_wolfSpot->GetPos x )
set movey to ( 1A_comp_wolfSpot->GetPos y )
set movez to ( ( 1A_comp_wolfSpot->GetPos z ) + 150 )
set noGreet to 1
AIWander 300 0 0 0 0
SetPos X, movex
SetPos Y, movey
SetPos Z, movez
set movecheck to 1
endif
if ( GetPCSleep == 1 )
set p_level to ( Player->GetLevel )
set p_health to ( 10 * p_level + 50 )
set p_strength to ( 2 * p_level + 50 )
if ( p_strength > 100 )
set p_strength to 100
endif
SetHealth p_health
SetStrength p_strength
return
endif
if ( Player->GetEffect sEffectLevitate == 1 )
if ( flyCheck == 0 )
cast 1a_comp_wolf_lev_bogus player
addspell 1a_comp_wolf_lev
set flyCheck to 1
endif
elseif ( Player->GetEffect sEffectLevitate == 0 )
if ( flyCheck == 1 )
removespell 1a_comp_wolf_lev
set flyCheck to 0
endif
endif
;old code before change
;wait in place when player levitates
; if ( Player->GetEffect sEffectLevitate == 1 )
; AiWander 0 0 0 0
; set spot_flw to 0
; return ; So the following If won't hit
;endif
;End Spirithawke change
; Was not following before?
if ( spot_flw == 0 )
set spot_flw to 1
set p_speed to ( ( Player->GetSpeed ) + 70 )
set p_level to ( Player->GetLevel )
set p_endurance to ( 2 * p_level + 45 )
set p_agility to ( 1.5 * p_level + 45 )
if ( p_endurance > 100 )
set p_endurance to 100
endif
if ( p_agility > 100 )
set p_agility to 100
endif
SetSpeed p_speed
setEndurance p_Endurance
setAgility p_agility
return
endif
; No warp in combat
if ( no_warp_check > 0 )
if ( Player->GetSpellReadied )
return
endif
if ( Player->GetWeaponDrawn )
return
endif
endif
set px to ( Player->GetPos x )
set py to ( Player->GetPos y )
if ( doOnce1 == 0 )
set ax to ( Player->GetPos x )
set ay to ( Player->GetPos y )
set az to ( Player->GetPos z )
set doOnce1 to 1
endif
set t1 to ( px - ax )
set t1 to ( t1 * t1 )
set t2 to ( py - ay )
set t2 to ( t2 * t2 )
set t1 to ( t1 + t2 )
set coDist1 to ( GetSquareRoot, t1 )
if ( coDist1 > 360 )
set doOnce1 to 0
endif
if ( coDist1 > 180 )
if ( doOnce2 == 0 )
set bx to ( Player->GetPos x )
set by to ( Player->GetPos y )
set bz to ( Player->GetPos z )
set doOnce2 to 1
endif
endif
set t3 to ( px - bx )
set t3 to ( t3 * t3 )
set t4 to ( py - by )
set t4 to ( t4 * t4 )
set t3 to ( t3 + t4 )
set coDist2 to ( GetSquareRoot, t3 )
if ( coDist2 > 360 )
set doOnce2 to 0
endif
;OLD CODE before Ultimate Galleon fix
; if ( warp == 0 )
; if ( coDist1 > 300 )
; if ( GetDistance Player > 680 )
; SetPos x ax
; SetPos y ay
; SetPos z az
; AiFollow Player 0 0 0 0
; elseif ( warp == 0 )
; if ( coDist2 > 300 )
; if ( GetDistance Player > 680 )
; SetPos x bx
; SetPos y by
; SetPos z bz
; AiFollow Player 0 0 0 0
; endif
; endif
; endif
; endif
; endif
; New warp, compatible with the Ultimate Galleon door
if ( warp == 0 )
if ( GetDistance player > 680 )
if ( coDist1 > 300 )
if ( coDist1 < 680 ) ; this prevents the "warping back" effect
SetPos X, ax
SetPos Y, ay
SetPos Z, az
AiFollow player 0 0 0 0
endif
elseif ( coDist2 > 300 )
if ( coDist2 < 680 ) ; this prevents the "warping back" effect
SetPos X, bx
SetPos Y, by
SetPos Z, bz
AiFollow player 0 0 0 0
endif
endif
endif
endif
else ; AIPackage != 3
if ( movecheck == 0 ) ;no changing his speed while moving out of the way as he will be following once again - Spirithawke
if ( Spot_flw > 0 )
SetSpeed 30
set Spot_flw to 0
endif
endif
endif
endHopefully someone finds this useful. Cheers  Spirithawke |
|
|
|
Post by blockhead on Dec 12, 2012 13:47:32 GMT
A question: If it it is shifting him up, would it put him into the ceiling if one is in an interior that uses a smaller tile set? p.s. Morrowind still rules, in my book.  |
|
|
|
Post by Emma on Dec 12, 2012 17:32:28 GMT
We did this in a somewhat other way with some of our other companions. I'll post the script from Beryl here:
begin 1gr_newCompScript
short companion
short noLore
short c_move
short c_speed
short c_athletics
short c_marksman
short p_health
short p_fatigue
short p_magicka
short m_set
short h_check
short p_check
short n_check
short c_once
short r_once
short noGreet
short oneTime
short doOnce1
short doOnce2
short warp
short flyCheck
short wwCheck
short weapUse
short combatDone
short combatCheck
short combatMode
short soundPlayed
Short DTNPS_MoveOnce_NotMenu
Short DTNPS_HandlePotions
Long DTNPS_Count_HealthExclusive
Long DTNPS_Count_HealthQuality
Long DTNPS_Count_HealthStandard
Long DTNPS_Count_HealthTotal
float z_fly
float timer
float sheatheTimer
float counter
float px
float py
float ax
float ay
float az
float bx
float by
float bz
float t1
float t2
float t3
float t4
float coDist1
float coDist2
float DTNPS_Timer_Health
if ( GetCurrentAIPackage != 3 )
setSpeed 40
endif
if ( weapUse == 1 )
if ( Player->GetWeaponType <= 8 )
setmarksman 0
elseif ( weapUse == 1 )
if ( Player->GetWeaponType >= 9 )
setmarksman 200
endif
endif
endif
; Potion-saver by DinkumThinkum
If ( GetHealth < 1 )
Set DTNPS_HandlePotions to 0
ElseIf ( GetFatigue < 1 )
Set DTNPS_HandlePotions to 0
ElseIf ( MenuMode == 1 )
Set DTNPS_HandlePotions to 0
Else
Set DTNPS_HandlePotions to 1
EndIf
If ( DTNPS_HandlePotions == 0 )
Set DTNPS_MoveOnce_NotMenu to 0
Set DTNPS_Timer_Health to 99
Set DTNPS_Count_HealthTotal to ( DTNPS_Count_HealthExclusive + DTNPS_Count_HealthQuality + DTNPS_Count_HealthStandard )
If ( DTNPS_Count_HealthTotal > 0 )
While ( DTNPS_Count_HealthExclusive >= 64 )
AddItem "p_restore_health_e" 64
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive - 64 )
EndWhile
While ( DTNPS_Count_HealthExclusive >= 8 )
AddItem "p_restore_health_e" 8
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive - 8 )
EndWhile
While ( DTNPS_Count_HealthExclusive >= 1 )
AddItem "p_restore_health_e" 1
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive - 1 )
EndWhile
While ( DTNPS_Count_HealthQuality >= 64 )
AddItem "p_restore_health_q" 64
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality - 64 )
EndWhile
While ( DTNPS_Count_HealthQuality >= 8 )
AddItem "p_restore_health_q" 8
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality - 8 )
EndWhile
While ( DTNPS_Count_HealthQuality >= 1 )
AddItem "p_restore_health_q" 1
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality - 1 )
EndWhile
While ( DTNPS_Count_HealthStandard >= 64 )
AddItem "p_restore_health_s" 64
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard - 64 )
EndWhile
While ( DTNPS_Count_HealthStandard >= 8 )
AddItem "p_restore_health_s" 8
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard - 8 )
EndWhile
While ( DTNPS_Count_HealthStandard >= 1 )
AddItem "p_restore_health_s" 1
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard - 1 )
EndWhile
EndIf
ElseIf ( DTNPS_HandlePotions == 1 )
If ( DTNPS_MoveOnce_NotMenu == 0 )
Set DTNPS_MoveOnce_NotMenu to 1
While ( GetItemCount "p_restore_health_e" > 64 )
RemoveItem "p_restore_health_e" 64
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive + 64 )
EndWhile
While ( GetItemCount "p_restore_health_e" > 8 )
RemoveItem "p_restore_health_e" 8
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive + 8 )
EndWhile
While ( GetItemCount "p_restore_health_e" > 1 )
RemoveItem "p_restore_health_e" 1
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive + 1 )
EndWhile
While ( GetItemCount "p_restore_health_q" >= 64 )
RemoveItem "p_restore_health_q" 64
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality + 64 )
EndWhile
While ( GetItemCount "p_restore_health_q" >= 8 )
RemoveItem "p_restore_health_q" 8
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality + 8 )
EndWhile
While ( GetItemCount "p_restore_health_q" >= 1 )
RemoveItem "p_restore_health_q" 1
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality + 1 )
EndWhile
While ( GetItemCount "p_restore_health_s" >= 64 )
RemoveItem "p_restore_health_s" 64
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard + 64 )
EndWhile
While ( GetItemCount "p_restore_health_s" >= 8 )
RemoveItem "p_restore_health_s" 8
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard + 8 )
EndWhile
While ( GetItemCount "p_restore_health_s" >= 1 )
RemoveItem "p_restore_health_s" 1
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard + 1 )
EndWhile
EndIf
Set DTNPS_Count_HealthTotal to ( DTNPS_Count_HealthExclusive + DTNPS_Count_HealthQuality + DTNPS_Count_HealthStandard )
If ( DTNPS_Count_HealthTotal > 0 )
Set DTNPS_Timer_Health to ( DTNPS_Timer_Health + GetSecondsPassed )
If ( GetItemCount "p_restore_health_e" > 0 )
Set DTNPS_Timer_Health to 0
ElseIf ( GetItemCount "p_restore_health_q" > 0 )
Set DTNPS_Timer_Health to 0
ElseIf ( GetItemCount "p_restore_health_s" > 0 )
Set DTNPS_Timer_Health to 0
ElseIf ( DTNPS_Timer_Health >= 1 )
If ( DTNPS_Count_HealthExclusive > 0 )
AddItem "p_restore_health_e" 1
Set DTNPS_Count_HealthExclusive to ( DTNPS_Count_HealthExclusive - 1 )
ElseIf ( DTNPS_Count_HealthQuality > 0 )
AddItem "p_restore_health_q" 1
Set DTNPS_Count_HealthQuality to ( DTNPS_Count_HealthQuality - 1 )
ElseIf ( DTNPS_Count_HealthStandard > 0 )
AddItem "p_restore_health_s" 1
Set DTNPS_Count_HealthStandard to ( DTNPS_Count_HealthStandard - 1 )
EndIf
EndIf
EndIf
EndIf
if ( MenuMode == 1 )
if ( GetPCSleep == 0 )
return
endif
endif
if ( combatCheck == 1 )
set sheatheTimer to sheatheTimer + GetSecondsPassed
if ( GetSoundPlaying, "Weapon Swish" == 1 )
set sheatheTimer to 0
return
elseif ( GetSoundPlaying, crossbowShoot == 1 )
set sheatheTimer to 0
return
elseif ( GetSoundPlaying, bowShoot == 1 )
set sheatheTimer to 0
return
elseif ( sheatheTimer > 4 )
if ( GetSoundPlaying "Weapon Swish" == 0 )
set sheatheTimer to 0
set soundPlayed to 1
endif
elseif ( sheatheTimer > 4 )
if ( GetSoundPlaying "crossbowShoot" == 0 )
set sheatheTimer to 0
set soundPlayed to 1
endif
elseif ( sheatheTimer > 4 )
if ( GetSoundPlaying "bowShoot" == 0 )
set sheatheTimer to 0
set soundPlayed to 1
endif
endif
endif
if ( soundPlayed == 1 )
set noSay to 1
1gr_comp4->StartCombat 1gr_comp4
set noSay to 0
; messagebox "Working"
set soundPlayed to 0
set combatCheck to 0
set combatMode to 0
set combatDone to 1
endif
if ( combatDone == 1 )
set timer to timer + GetSecondsPassed
if ( timer > 6 )
set timer to 0
set combatDone to 0
set warp to 0
endif
endif
if ( c_move == 1 )
if ( GetDistance Player > 100 )
set noGreet to 0
AIFollow Player 0 0 0 0
set c_move to 0
endif
endif
if ( GetCurrentAIPackage == 3 )
if ( GetPCSleep == 1 )
set p_health to ( Player->GetHealth )
set p_fatigue to ( Player->GetFatigue )
set p_magicka to ( Player->GetMagicka )
setHealth p_health
setFatigue p_fatigue
setMagicka p_magicka
endif
if ( flyCheck == 1 )
if ( GetWeaponDrawn == 0 )
set z_fly to ( Player->GetPos z )
SetPos z z_fly
elseif ( flyCheck == 1 )
if ( GetCurrentAIPackage != 3 )
if ( GetWeaponDrawn == 0 )
set z_fly to ( GetPos z )
SetPos z z_fly
endif
endif
endif
endif
if ( GetWeaponDrawn == 1 )
if ( flyCheck == 0 )
set combatCheck to 1
set combatMode to 1
set timer to 0
set warp to 1
return
elseif ( GetWeaponDrawn == 1 )
if ( flyCheck == 1 )
set combatDone to 1
set combatMode to 1
set timer to 0
set warp to 1
return
endif
endif
endif
if ( GetCurrentAIPackage == 3 )
set px to ( Player->GetPos x )
set py to ( Player->GetPos y )
if ( doOnce1 == 0 )
set ax to ( Player->GetPos x )
set ay to ( Player->GetPos y )
set az to ( Player->GetPos z )
set doOnce1 to 1
endif
set t1 to ( px - ax )
set t1 to ( t1 * t1 )
set t2 to ( py - ay )
set t2 to ( t2 * t2 )
set t1 to ( t1 + t2 )
set coDist1 to ( GetSquareRoot, t1 )
if ( coDist1 > 360 )
set doOnce1 to 0
endif
if ( coDist1 > 180 )
if ( doOnce2 == 0 )
set bx to ( Player->GetPos x )
set by to ( Player->GetPos y )
set bz to ( Player->GetPos z )
set doOnce2 to 1
endif
endif
set t3 to ( px - bx )
set t3 to ( t3 * t3 )
set t4 to ( py - by )
set t4 to ( t4 * t4 )
set t3 to ( t3 + t4 )
set coDist2 to ( GetSquareRoot, t3 )
if ( coDist2 > 360 )
set doOnce2 to 0
endif
if ( warp == 0 )
if ( coDist1 > 300 )
if ( GetDistance Player > 680 )
SetPos x ax
SetPos y ay
SetPos z az
; set doOnce1 to 0
AiFollow Player 0 0 0 0
elseif ( warp == 0 )
if ( coDist2 > 300 )
if ( GetDistance Player > 680 )
SetPos x bx
SetPos y by
SetPos z bz
; set doOnce2 to 0
AiFollow Player 0 0 0 0
endif
endif
endif
endif
endif
endif
if ( counter < 20 )
set counter to counter + 1
return
endif
set counter to 0
if ( GetCurrentAiPackage == 3 )
set c_speed to ( ( Player->GetSpeed ) * 2.25 )
set c_athletics to ( ( Player->GetAthletics ) * 2.25 )
setSpeed c_speed
setAthletics c_athletics
if ( GetDistance Player < 80 )
set noGreet to 1
AIWander 300 0 0 0 0
set c_move to 1
endif
if ( Player->GetEffect sEffectLevitate == 1 )
if ( flyCheck == 0 )
cast 1gr_lev_bogus player
addspell 1gr_lev
set flyCheck to 1
endif
endif
if ( Player->GetEffect sEffectLevitate == 0 )
if ( flyCheck == 1 )
removespell 1gr_lev
set flyCheck to 0
endif
endif
if ( Player->GetEffect sEffectWaterWalking == 1 )
if ( wwCheck == 0 )
cast 1gr_ww_bogus player
addspell 1gr_ww
set wwCheck to 1
endif
endif
if ( Player->GetEffect sEffectWaterWalking == 0 )
if ( wwCheck == 1 )
removespell 1gr_ww
set wwCheck to 0
endif
endif
if ( GetPCSneaking == 1 )
ForceSneak
elseif ( GetPCSneaking == 0 )
ClearForceSneak
endif
if ( n_check == 1 )
if ( GetHealthGetRatio > 0.35 )
set n_check to 0
endif
endif
if ( m_set == 1 )
set c_marksman to ( ( Player->GetLevel ) + 35 )
setMarksman c_marksman
endif
endif
; if ( GetItemCount p_restore_health_b >= 1 )
; set p_check to 1
; elseif ( GetItemCount p_restore_health_c >= 1 )
; set p_check to 1
; elseif ( GetItemCount p_restore_health_e >= 1 )
; set p_check to 1
; elseif ( GetItemCount p_restore_health_q >= 1 )
; set p_check to 1
; elseif ( GetItemCount p_restore_health_s >= 1 )
; set p_check to 1
; else
; set p_check to 0
; endif
; endif
endif
end
These parts makes her temporary stop following and step aside:
if ( GetDistance Player < 80 )
set noGreet to 1
AIWander 300 0 0 0 0
set c_move to 1
endif
if ( c_move == 1 )
if ( GetDistance Player > 100 )
set noGreet to 0
AIFollow Player 0 0 0 0
set c_move to 0
endif
endif
It's two approaches. Ours probably "looks neater" ingame as she won't jump, but the disadvantage is that if the player switches cell during the time she is in wander mode, she won't follow. It's normally no high risk, but if you have several companions that are all stepping aside, it's a high risk that someone will remain in the old cell. I think that's why we left it out from Spot; most people used him in combination with a human companion.
I must admit that I haven't released a mod for Morrowind since january 2010 - I've been way too busy modding Oblivion and Skyrim. Still, Morrowind is in my heart still the best of the games, and there are times when I'm very tempted to do something new for it. I think I just fear that I'm too "rusty" after this long absence..
|
|
|
|
Post by Spirithawke on Dec 12, 2012 20:33:30 GMT
A question: If it it is shifting him up, would it put him into the ceiling if one is in an interior that uses a smaller tile set? p.s. Morrowind still rules, in my book. I suppose there is a chance of that, but consider this: Once you are far enough away he will shift into follow mode and either A: walk out of the ceiling to follow you or B: warp to you once you are warp distance away. |
|
